// Methode: DBZ_GetFromWebArea
  // Anwender (OS): O. Zillgen, 21.09.14, 14:50:49
  // vcs_Version=000000
  // Parameter
  // 1 $wa_AreaObjName
  // 2 $P_givenTextArray
  // 3 $tagName
  // 4 $attributeName
  // => 
  // Beschreibung
  // 
  //
  //
  // ----------------------------------------------------

C_TEXT($wa_AreaObjName;$1;$tagName;$3;$attributeName;$4;$js)
C_POINTER($P_givenTextArray;$2)
C_LONGINT($numTags;$a)

If (Count parameters>=3)
$wa_AreaObjName:=$1
$P_givenTextArray:=$2
$tagName:=$3
If (Count parameters>=4)
$attributeName:=$4
End if 
End if 

Case of 
: ($wa_AreaObjName="")
: (Nil($P_givenTextArray))
: (Type($P_givenTextArray->)#Text array)
: ($tagName="")
Else 

Case of 
: ($attributeName#"")
: (($tagName="img") | ($tagName="iframe"))
$attributeName:="src"
: ($tagName="a")
$attributeName:="href"

Else 

End case 

If ($attributeName="")
  //through error
Else 
$numTags:=WA Evaluate JavaScript(*;$wa_AreaObjName;"document.getElementsByTagName('"+$tagName+"').length";Is longInt)
ARRAY TEXT($P_givenTextArray->;$numTags)
For ($a;1;$numTags)
$js:="document.getElementsByTagName('"+$tagName+"')["+String($a-1)+"]."+$attributeName
$P_givenTextArray->{$a}:=WA Evaluate JavaScript(*;$wa_AreaObjName;$js;Is text)
End for 
End if 
End case 


  // *****  Ende der Methode: DBZ_GetFromWebArea  *****